Buffer.loadDialog & DiskIn problem

[kanonas]

Hello everybody,
I want to make a 4 sample player. I tried to use DiskIn because i need long audiofiles to be loaded.
My problem is that i don't know how to use Buffer.loadDialog

b = Buffer.loadDialog(s);
x = { DiskIn.ar(2, b) }.play;

With this code i can't hear anything, neither with this::

b = Buffer.loadDialog(s, action: { arg buffer;
x = { DiskIn.ar(2, buffer, 1) }.play;          
});

[dewdrop_world]

I think the problem here is that DiskIn expects part of the sound file to be loaded into the buffer, and the file should be left open so that DiskIn can get more audio from disk as needed. Buffer:loadDialog doesn't do that -- it closes the file after filling the buffer from disk, and this is (most likely) causing DiskIn not to work.

Also, since your code doesn't specify a buffer size, it will load the entire file into server memory. In that case, DiskIn is superfluous because the whole point of that unit generator is to read audio incrementally into a smaller buffer.

I would suggest something like this. There is a bunch of stuff in here that I don't have time to explain tonight, but ask more questions and I'll be happy to fill in the blanks. Keeping track of the buffers and synths is not covered in this code but will be very important for handling multiple buffers and files.

James

Code:

(
CocoaGUI.dialog.getPaths({ |path|
var sf = SoundFile.openRead(path[0]), condition = Condition.new, defname;
if(sf.notNil and: { sf.isOpen }) {
protect {
fork {
defname = "diskin" ++ sf.numChannels;
SynthDef(defname, { |buffer, out, loop = 1|
Out.ar(out, DiskIn.ar(sf.numChannels, buffer, loop))
}).send(s);
b = Buffer.cueSoundFile(s, path[0],
startFrame: 0,
numChannels: sf.numChannels,
bufferSize: 131072);
s.sync(condition);
x = Synth(defname, [buffer: b]);
}
} {
sf !? { sf.close };
}
} {
"% is not a valid soundfile.".format(path[0]).die;
};
});
)


x.free;