possible to refer to an individual channel within a multichannel bus object?

[Charles]

Hi, I'm yet another user New to SC.
Could anyone help me with this very simple question?

if I have a bus object, say
a = Bus.audio(s, 6);

how can I refer to just individual channels within the six channels of object 'a'

For example...

Code:

//Load a simple sine SynthDef to default server
(
var outFunc;

outFunc = {arg outBus = 0, freq = 220;
var outSignal;
outSignal = SinOsc.ar(freq, 0, 0.02);
Out.ar(outBus, outSignal);
};

SynthDef.new("simpleSynth", outFunc).load(s);
)

// Fill an array with 6 synths each outputting 
// to a seperate channel within bus06
(
var bus06, synthArr;

bus06 = Bus.audio(s, 6);
synthArr = Array.new(0);

6.do({arg i;
synthArr = synthArr.add(Synth.new("simpleSynth", ["outBus", 0/*What Goes Here?*/,"freq", (i * 100)]));
};);
)

is it possible to use the 'Do' loop to fill the array with 6 overtones of 100hz, each going to a separate channel?

[joshp]

To the first part... that is a little tricky. Does this work?

Code:

a  = Bus.audio(s, 6);

a.index + 0
a.index + 1

Which would make this work (I added 1 to i in the 'freq' parameter... otherwise the first partial is '0'):

Code:

//Load a simple sine SynthDef to default server
(
var outFunc;

outFunc = {arg outBus = 0, freq = 220;
var outSignal;
outSignal = SinOsc.ar(freq, 0, 0.02);
Out.ar(outBus, outSignal);
};

SynthDef.new("simpleSynth", outFunc).load(s);
)

// Fill an array with 6 synths each outputting 
// to a seperate channel within bus06
(
var bus06, synthArr;

bus06 = Bus.audio(s, 6);
synthArr = Array.new(0);

bus06.numChannels.do({arg i;
synthArr = synthArr.add(
Synth.new("simpleSynth", ["outBus", bus06.index + i, "freq", (i + 1 * 100)]));
};);
)

Hope that helps.

Josh

[Charles]

Thanks! that makes thing easy! I was thinking that creating a Bus Object would allocate busses with non sequential indexes if it were so inclined, but it looks as if this is not the case.

when using .control and .audio messages to crate multi channel bus objects, are the indexes that are used always sequential? I did some testing and it looks like they are.  for example....

Code:

(
a = Bus.control(s, 2);
b = Bus.control(s, 2);

a.free;
a = Bus.control(s, 4);
)

..will output this line:

Bus(control, 4, 4, localhost)

...implying that control buses with indexes '0' and '1' were not used because there was not four sequential indexes available.

is there a situation were this would work otherwise?

[joshp]

Yes... they are always a contiguous block and sequential. Out inside UGens relies on this.

Josh